source: DCWoRMS/branches/coolemall/simulator/xslt/debb/LoadCalendarUpdater.xsl @ 1302

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:dcworms="DCWormsResSchema.xsd"
        xmlns:debb2dcworms="../../debb2dcworms.xsd"
        xmlns:fun="http://whatever">

        <!-- Specification of the output document -->
        <xsl:output method="xml" version="1.0" encoding="UTF-8"
                indent="yes" />

        <!-- Root of the DCworms XML document -->
        <xsl:variable name="rootDoc" select="/" />

        <xsl:param name="additionalInformationFileName" select="additionalInformationFileName" />
        <xsl:param name="estimatorsInformationFileName" select="estimatorsInformationFileName" />

        <xsl:variable name="nestedDoc"
                select="document($additionalInformationFileName)" />
                
        <xsl:variable name="estimatorsDoc"
                select="document($estimatorsInformationFileName)" />

        <xsl:template match="/">
                <xsl:apply-templates select="environment" />
        </xsl:template>

        <xsl:template match="environment">
                <xsl:copy>
                        <xsl:copy-of select="@*" />
                        <xsl:apply-templates select="timeEstimationPlugin" />
                        <xsl:apply-templates select="resources" />
                        <xsl:apply-templates select="templates"/>
                </xsl:copy>
        </xsl:template>

        <xsl:template match="resources">
                <xsl:copy copy-namespaces="no">
                <xsl:copy-of select="@*" />
                        <xsl:apply-templates select="//resources/computingResource" />
                        <xsl:apply-templates select="scheduler"/>
                </xsl:copy>
        </xsl:template>


        
        <xsl:template match="loadCalendar">
                <xsl:element name="loadProfile">
                        <xsl:copy-of select="." copy-namespaces="no" />
                </xsl:element>
        </xsl:template>


        <xsl:template match="computingResourceTemplate | computingResource">
                <xsl:copy copy-namespaces="no">
                        <xsl:copy-of select="@*" />
                        <!-- Find nested elements in appropriate order and copy them -->
                        
                        <!-- templateId -->
                        <xsl:apply-templates select="templateId" />
                        <!-- location -->
                        <xsl:apply-templates select="location" />
                        <!-- parameter -->
                        <xsl:apply-templates select="parameter" />
                                                                        
                        
                        <xsl:variable name="resourceClass" select="@class"/>
                        <xsl:variable name="resourceName" select="@name"/>
                        <xsl:variable name="debbFullPath" select="fun:getFullPath(.)"/>
                        
                        <xsl:if test="not(templateId)">
                                <xsl:variable name="loadCalendar" select="fun:getLoadCalendar($resourceClass, $debbFullPath)"/>
                                <xsl:variable name="hasProfile" select="profile != ''"/>
        
                                <xsl:if test="$hasProfile = false() and $loadCalendar != ''">
                                        <xsl:element name="profile">
                                                <xsl:element name="loadProfile">
                                                        <xsl:element name="loadEstimationPlugin">
                                                                <xsl:element name="name">
                                                                        <xsl:value-of select="fun:getLoadEstimator($resourceClass)"/>
                                                                </xsl:element>
                                                        </xsl:element> 
                                                        <xsl:copy-of
                                                                        select="$loadCalendar" />
                                                </xsl:element>
                                        </xsl:element>
                                </xsl:if>
                        </xsl:if>
                        
                        <!-- profile -->
                        <xsl:apply-templates select="profile" />
                        <!-- device -->
                        <xsl:apply-templates select="device" />
                        <!-- resourceUnit -->
                        <xsl:apply-templates select="resourceUnit" />
                        <!-- computingResource -->
                        <xsl:apply-templates select="computingResource" />
                                                
                </xsl:copy>
        </xsl:template>
        
        
        <xsl:function name="fun:getLoadCalendar">
                <xsl:param name="computingResourceClass"/>
                <xsl:param name="computingResourceName"/>
                
                <xsl:variable name="loadCalendar" >
                        <xsl:choose>
                                <xsl:when test="$nestedDoc//computingResource[@class=$computingResourceClass and @name=$computingResourceName]">
                                        <xsl:copy-of select="$nestedDoc//computingResource[@class=$computingResourceClass and @name=$computingResourceName]/loadCalendar"/>
                                </xsl:when>
                                <xsl:when test="$nestedDoc//computingResource[@class=$computingResourceClass]">
                                        <xsl:copy-of select="$nestedDoc//computingResource[@class=$computingResourceClass and not(@name)]/loadCalendar"/>
                                </xsl:when>
                                <xsl:otherwise>
                                </xsl:otherwise>
                        </xsl:choose>
                </xsl:variable>
                <xsl:copy-of select="$loadCalendar"/>
        </xsl:function>

        <xsl:function name="fun:getLoadEstimator">
                <xsl:param name="computingResourceClass"/>
   
                <xsl:variable name="estimatorName" >
                        <xsl:choose>
                                <xsl:when test="$estimatorsDoc//loadEstimationPlugin[resources/class=$computingResourceClass]/name !=''">
                                        <xsl:value-of select="$estimatorsDoc//loadEstimationPlugin[resources/class=$computingResourceClass ]/name"/>
                                </xsl:when>
                                <xsl:otherwise>
                                </xsl:otherwise>
                        </xsl:choose>
                </xsl:variable>
                <xsl:value-of select="$estimatorName"/>
        </xsl:function>
        
        <xsl:template match="timeEstimationPlugin | scheduler | device | resourceUnit | parameter | location | powerProfile | airThroughputProfile">
                <xsl:copy-of select="." copy-namespaces="no" />
        </xsl:template>

        <xsl:function name="fun:getFullPath">
                <xsl:param name="currentComputingResource"/>
                <xsl:variable name="ancestors" select="$currentComputingResource/ancestor::computingResource/@name"/>

                
                <xsl:variable name="fullPath">
                        <xsl:for-each select="1 to count($ancestors)">
                                <xsl:variable name="index" select="." />
                                <xsl:value-of select="$ancestors[$index]"/>
                                <xsl:text>/</xsl:text>
                        </xsl:for-each> 
                        <xsl:value-of select="$currentComputingResource/@name"></xsl:value-of>  
                </xsl:variable>
                
                <xsl:value-of select="$fullPath"/>
        </xsl:function>

        <xsl:template match="profile">
                <xsl:copy copy-namespaces="no">
                <xsl:copy-of select="@*" />
                
                        <xsl:apply-templates select="powerProfile" />
                        <xsl:apply-templates select="airThroughputProfile" />
                        
                        <xsl:variable name="resourceClass" select="../@class"></xsl:variable>
                        <xsl:variable name="resourceName" select="../@name"></xsl:variable>
                        <xsl:variable name="debbFullPath" select="fun:getFullPath(..)"/>
                        
                        <xsl:variable name="loadCalendar" select="fun:getLoadCalendar($resourceClass, $debbFullPath)"/>
                        <xsl:if test="$loadCalendar != ''">
                                <xsl:element name="loadProfile">
                                        <xsl:element name="loadEstimationPlugin">
                                                <xsl:element name="name">
                                                        <xsl:value-of select="fun:getLoadEstimator($resourceClass)"/>
                                                </xsl:element>
                                        </xsl:element> 
                                        <xsl:copy-of
                                                select="$loadCalendar" />
                                </xsl:element>
                        </xsl:if>
                </xsl:copy>

        </xsl:template>


        <xsl:template match="templates">
                <xsl:copy copy-namespaces="no">
                        <xsl:apply-templates/>  
                </xsl:copy>
                
        </xsl:template>
        
        <xsl:template match="@*|node()">
                <xsl:copy>
                        <xsl:apply-templates select="@*" />
                        <xsl:apply-templates />
                </xsl:copy>
        </xsl:template>

</xsl:stylesheet>