source: DCWoRMS/trunk/src/test/DEBBTranslator/xml/DCWoRMSDEBBUpdater.xsl @ 847

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:dcworms="DCWormsResSchema.xsd"
        xmlns:debb2dcworms="../../debb2dcworms.xsd">

        <!-- Specification of the output document -->
        <xsl:output method="xml" version="1.0" encoding="UTF-8"
                indent="yes" />

        <!-- Root of the DCWoRMS XML document -->
        <xsl:variable name="rootDoc" select="/" />

        <!-- Information about schedulers and estimators -->
        <xsl:param name="additionalInformationFileName" select="additionalInformationFileName" />


        <xsl:variable name="nestedDoc"
                select="document($additionalInformationFileName)" />

        <xsl:template match="/">
                <xsl:comment>
                        This is DEBB information (taken from PLM XML and DEBBComponent
                        files), updated by schedulers and estimators. Moreover, all elements
                        are sorted and appear in correct order, according to the schema.
                </xsl:comment>
                <xsl:comment>
                        Schedulers and estimators information is loaded from
                        <xsl:value-of select="$additionalInformationFileName" />
                        file
                </xsl:comment>

                <xsl:apply-templates select="environment" />

        </xsl:template>

        <xsl:template match="environment">
                <xsl:copy>
                        <xsl:copy-of select="@*" />
                        <xsl:apply-templates select="resources" />
                </xsl:copy>
        </xsl:template>

        <xsl:template match="resources">
                <xsl:copy copy-namespaces="no">
                        <xsl:apply-templates select="//resources/computingResource" />
                        <xsl:element name="scheduler">
                                <xsl:attribute name="class">Cluster</xsl:attribute>
                                <xsl:attribute name="name">cluster</xsl:attribute>
                                <xsl:apply-templates select="$nestedDoc//schedulingPlugin" />
                        </xsl:element>
                </xsl:copy>
        </xsl:template>

        <xsl:template match="schedulingPlugin">
                <xsl:element name="schedulingPlugin">
                        <xsl:element name="name">
                                <xsl:value-of select="name" />
                        </xsl:element>
                        <xsl:if test="frequency != ''">
                                <xsl:element name="frequency">
                                        <xsl:value-of select="frequency"/>
                                </xsl:element>
                        </xsl:if>
                </xsl:element>
                <xsl:element name="managedComputingResources">
                        <!-- TODO: This parameter should be taken from somewhere. -->
                        <xsl:attribute name="include">false</xsl:attribute>
                        <!-- Find appropriate resources (identified by class, type and name(s)) and add their names here -->
                        <xsl:variable name="resourceClass"><xsl:value-of select="resources/class"/></xsl:variable>
<!--                    <xsl:value-of select="$resourceClass"/>-->
                        <xsl:variable name="resourceType"><xsl:value-of select="resources/type"/></xsl:variable>
<!--                    <xsl:value-of select="$resourceType"/>-->
                        <xsl:variable name="resourceNames"><xsl:value-of select="resources/name"/></xsl:variable>
                        <xsl:variable name="xpath">$rootDoc//computingResource[@class=<xsl:value-of select="$resourceClass"/> and @type=<xsl:value-of select="$resourceType"/>]</xsl:variable>
<!--                    <xsl:value-of select="$xpath"></xsl:value-of>-->
                        <xsl:choose>
                                <xsl:when test="$resourceClass != '' and $resourceType != ''">
<!--                                    <xsl:value-of select="$resourceClass"/>-->
<!--                                    <xsl:value-of select="$resourceType"/>-->
                                        <xsl:apply-templates select="$rootDoc//computingResource[@class=$resourceClass and @type=$resourceType]" mode="addResorceName"/>
                                </xsl:when>
                                <xsl:otherwise>
<!--                                    <xsl:value-of select="$resourceClass"/>-->
                                        <xsl:apply-templates select="$rootDoc//computingResource[@class=$resourceClass]" mode="addResorceName"/>
                                </xsl:otherwise>
                        </xsl:choose>
                        
                        
                        
                </xsl:element>
        </xsl:template>

        <xsl:template match="computingResource">
                <xsl:copy copy-namespaces="no">
                        <xsl:copy-of select="@*" />
                        <!-- Find nested elements in appropriate order and copy them -->
                        <!-- resourceUnit -->
                        <xsl:apply-templates select="resourceUnit" />
                        <!-- parameter -->
                        <xsl:apply-templates select="parameter" />
                        <!-- profile -->
                        <xsl:apply-templates select="profile" />
                        <!-- location -->
                        <xsl:apply-templates select="location" />
                        <!-- computingResource -->
                        <xsl:apply-templates select="computingResource" />
                </xsl:copy>
        </xsl:template>

        <xsl:template match="computingResource" mode="addResorceName">
                <xsl:element name="resourceName">
                        <xsl:value-of select="../@name"></xsl:value-of>
                </xsl:element>
        </xsl:template>
        
        <xsl:template match="resourceUnit | parameter | profile | location">
                <xsl:copy-of select="." copy-namespaces="no" />
        </xsl:template>

        <!-- <xsl:template match="@*|node()"> <xsl:copy> <xsl:apply-templates select="@*"/> 
                <xsl:apply-templates/> </xsl:copy> </xsl:template> -->

</xsl:stylesheet>