source: DCWoRMS/trunk/src/test/DEBBTranslator/xml/PLMXMLTranslator.xsl @ 800

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:plm="http://www.plmxml.org/Schemas/PLMXMLSchema"
        xmlns:cim="http://www.coolemall.eu/DEBBComponent" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">

        <!-- Importing xslt for translating debb components -->
        <xsl:import href="DEBBComponentTranslator.xsl" />

        <!-- Information for mapping of DEBB classes into DCWoRMS computingResource 
                classes -->
        <xsl:param name="computingResourceClasses" select="computingResourceClasses" />

        <!-- Information for mapping of resource classes into DCWoRMS resourceUnits 
                classes -->
        <!-- (Needed to pass to DEBB Components xslt) -->
        <xsl:param name="resourceUnitClasses" select="resourceUnitClasses" />

        <!-- Specification of the output document -->
        <xsl:output method="xml" version="1.0" encoding="UTF-8"
                indent="yes" />

        <!-- Root of the PLM XML document -->
        <xsl:variable name="rootDoc" select="/" />

        <!-- Default DEBBComponents file name (used if it is not specified in PLM 
                XML file) -->
        <xsl:variable name="defaultDEBBComponentsFileName" select="'DEBBComponents.xml'" />


        <xsl:template match="/">
                <xsl:element name="environment">
                        <xsl:attribute name="xsi:noNamespaceSchemaLocation">DCWormsResSchema.xsd</xsl:attribute>
                        <xsl:element name="resources">
                                <xsl:apply-templates select="//plm:InstanceGraph" />
                                <xsl:element name="scheduler"></xsl:element>
                        </xsl:element>
                </xsl:element>
        </xsl:template>

        <xsl:template match="plm:InstanceGraph">
                <!-- Finding root DEBB -->
                <xsl:variable name="rootRef" select="@rootRefs" />
                <xsl:apply-templates select="plm:ProductInstance[@id=$rootRef]" />
        </xsl:template>

        <xsl:template match="plm:ProductInstance">
                <xsl:variable name="partRef" select="@partRef" />
                <!-- Get rid of # at the beginning -->
                <xsl:variable name="productInstanceId" select="translate($partRef, '#', '')" />

                <xsl:if test="not (starts-with(@name, 'Sensor'))">
                        <!-- We have to get rid of sensors, which make only problems here -->
                        <xsl:element name="computingResource">
                                <xsl:attribute name="name"><xsl:value-of select="@name" /></xsl:attribute>

                                <!-- Find corresponding ProductRevisionView and let it translate itself -->
                                <xsl:apply-templates
                                        select="//plm:ProductRevisionView[@id=$productInstanceId]" />

                                <!-- Add hostnames, labels, locations, sequences, etc. -->
                                <xsl:variable name="debbHostname"
                                        select="plm:UserData/plm:UserValue[@title='hostname']/@value" />
                                <xsl:if test="$debbHostname != ''">
                                        <xsl:element name="parameter">
                                                <xsl:attribute name="name">hostname</xsl:attribute>
                                                <xsl:element name="value">
                                                        <xsl:value-of select="$debbHostname" />
                                                </xsl:element>
                                        </xsl:element>
                                </xsl:if>
                                <xsl:variable name="debbLabel"
                                        select="plm:UserData/plm:UserValue[@title='label']/@value" />
                                <xsl:if test="$debbLabel != ''">
                                        <xsl:element name="parameter">
                                                <xsl:attribute name="name">label</xsl:attribute>
                                                <xsl:element name="value">
                                                        <xsl:value-of select="$debbLabel" />
                                                </xsl:element>
                                        </xsl:element>
                                </xsl:if>
                                <xsl:variable name="debbLocation"
                                        select="plm:UserData/plm:UserValue[@title='location']/@value" />
                                <xsl:if test="debbLocation != ''">
                                        <xsl:element name="parameter">
                                                <xsl:attribute name="name">location</xsl:attribute>
                                                <xsl:element name="value">
                                                        <xsl:value-of select="$debbLocation" />
                                                </xsl:element>
                                        </xsl:element>
                                </xsl:if>
                                <xsl:variable name="debbSequence"
                                        select="plm:UserData/plm:UserValue[@title='sequence']/@value" />
                                <xsl:if test="$debbSequence != ''">
                                        <xsl:element name="parameter">
                                                <xsl:attribute name="name">sequence</xsl:attribute>
                                                <xsl:element name="value">
                                                        <xsl:value-of select="$debbSequence" />
                                                </xsl:element>
                                        </xsl:element>
                                </xsl:if>
                        </xsl:element>
                </xsl:if>
        </xsl:template>

        <xsl:template match="plm:ProductRevisionView">
                <!-- instanceRefs contain space separated ids of nested DEBBs -->
                <xsl:variable name="tokenizedText" select="tokenize(@instanceRefs, ' ')" />

                <!-- DEBBLevel -->
                <xsl:variable name="debbLevel"
                        select="plm:UserData/plm:UserValue[@title='DEBBLevel']/@value" />
                <!-- DEBBComponentId -->
                <xsl:variable name="debbComponentId"
                        select="plm:UserData/plm:UserValue[@title='DEBBComponentId']/@value" />
                <!-- DEBBComponentFile -->
                <xsl:variable name="debbComponentFile"
                        select="plm:UserData/plm:UserValue[@title='DEBBComponentFile']/@value" />

                <xsl:attribute name="class">
                        <xsl:value-of select="$debbLevel" />
                </xsl:attribute>

                <xsl:if test="$debbComponentId != ''">
                        <xsl:attribute name="type">
                                <xsl:value-of select="$debbComponentId" />
                        </xsl:attribute>
                </xsl:if>

                <!-- Add DEBB information from DEBB Components file -->
                <xsl:choose>
                        <!-- DEBB Components file is defined -->
                        <xsl:when test="$debbComponentFile != ''">
                                <xsl:comment>
                                        DEBB Component file is
                                        <xsl:value-of select="$debbComponentFile" />
                                </xsl:comment>
                                <xsl:variable name="nestedDoc" select="document($debbComponentFile)" />
                                <xsl:apply-templates select="$nestedDoc//*[ComponentId=$debbComponentId]" />
                        </xsl:when>
                        <!-- DEBB Components file is not defined. Use default one. -->
                        <xsl:otherwise>
                                <xsl:comment>
                                        DEBB Component file is
                                        <xsl:value-of select="$defaultDEBBComponentsFileName" />
                                </xsl:comment>
                                <xsl:variable name="nestedDoc"
                                        select="document($defaultDEBBComponentsFileName)" />
                                <xsl:apply-templates select="$nestedDoc//*[ComponentId=$debbComponentId]">
                                        <xsl:with-param name="computingResourceClasses">
                                                <xsl:value-of select="$computingResourceClasses" />
                                        </xsl:with-param>
                                        <xsl:with-param name="resourceUnitClasses">
                                                <xsl:value-of select="$resourceUnitClasses" />
                                        </xsl:with-param>
                                </xsl:apply-templates>
                        </xsl:otherwise>
                </xsl:choose>

                <!-- Iterate children and ask them to translate themselves -->
                <xsl:for-each select="1 to count($tokenizedText)">
                        <xsl:variable name="index" select="." />
                        <xsl:apply-templates
                                select="$rootDoc//plm:ProductInstance[@id=$tokenizedText[$index]]" />
                </xsl:for-each>
        </xsl:template>
</xsl:stylesheet>